Gecko [ sachasauda.akalacademy.ac.in ]

Name	Size	Permission
Command	[ DIR ]	drwxr-xr-x
Liblist	[ DIR ]	drwxr-xr-x
MakeMaker	[ DIR ]	drwxr-xr-x
ParseXS	[ DIR ]	drwxr-xr-x
Typemaps	[ DIR ]	drwxr-xr-x
Liblist.pm	9.47 KB	-rw-r--r--
MANIFEST.SKIP	824 B	-rw-r--r--
MM.pm	2.06 KB	-rw-r--r--
MM_AIX.pm	1.53 KB	-rw-r--r--
MM_Any.pm	68.58 KB	-rw-r--r--
MM_BeOS.pm	982 B	-rw-r--r--
MM_Cygwin.pm	3.04 KB	-rw-r--r--
MM_DOS.pm	950 B	-rw-r--r--
MM_Darwin.pm	918 B	-rw-r--r--
MM_MacOS.pm	1.08 KB	-rw-r--r--
MM_NW5.pm	6.41 KB	-rw-r--r--
MM_OS2.pm	3.75 KB	-rw-r--r--
MM_QNX.pm	868 B	-rw-r--r--
MM_UWIN.pm	955 B	-rw-r--r--
MM_Unix.pm	91.82 KB	-rw-r--r--
MM_VMS.pm	59.65 KB	-rw-r--r--
MM_VOS.pm	723 B	-rw-r--r--
MM_Win32.pm	13.85 KB	-rw-r--r--
MM_Win95.pm	1.87 KB	-rw-r--r--
MY.pm	652 B	-rw-r--r--
MakeMaker.pm	91.59 KB	-rw-r--r--
Manifest.pm	22.52 KB	-rw-r--r--
Mkbootstrap.pm	3.11 KB	-rw-r--r--
Mksymlists.pm	10.5 KB	-rw-r--r--
ParseXS.pm	60.01 KB	-rw-r--r--
ParseXS.pod	3.74 KB	-rw-r--r--
Typemaps.pm	24.81 KB	-rw-r--r--
testlib.pm	891 B	-rw-r--r--
xsubpp	4.45 KB	-rwxr-xr-x

Code Editor : MM_Cygwin.pm

package ExtUtils::MM_Cygwin;

use strict;

use ExtUtils::MakeMaker::Config;
use File::Spec;

require ExtUtils::MM_Unix;
require ExtUtils::MM_Win32;
our @ISA = qw( ExtUtils::MM_Unix );

our $VERSION = '6.68';

=head1 NAME

ExtUtils::MM_Cygwin - methods to override UN*X behaviour in ExtUtils::MakeMaker

=head1 SYNOPSIS

use ExtUtils::MM_Cygwin; # Done internally by ExtUtils::MakeMaker if needed

=head1 DESCRIPTION

See ExtUtils::MM_Unix for a documentation of the methods provided there.

=over 4

=item os_flavor

We're Unix and Cygwin.

=cut

sub os_flavor {
    return('Unix', 'Cygwin');
}

=item cflags

if configured for dynamic loading, triggers #define EXT in EXTERN.h

=cut

sub cflags {
    my($self,$libperl)=@_;
    return $self->{CFLAGS} if $self->{CFLAGS};
    return '' unless $self->needs_linking();

my $base = $self->SUPER::cflags($libperl);
    foreach (split /\n/, $base) {
        /^(\S*)\s*=\s*(\S*)$/ and $self->{$1} = $2;
    };
    $self->{CCFLAGS} .= " -DUSEIMPORTLIB" if ($Config{useshrplib} eq 'true');

return $self->{CFLAGS} = qq{
CCFLAGS = $self->{CCFLAGS}
OPTIMIZE = $self->{OPTIMIZE}
PERLTYPE = $self->{PERLTYPE}
};

}

=item replace_manpage_separator

replaces strings '::' with '.' in MAN*POD man page names

=cut

sub replace_manpage_separator {
    my($self, $man) = @_;
    $man =~ s{/+}{.}g;
    return $man;
}

=item init_linker

points to libperl.a

=cut

sub init_linker {
    my $self = shift;

if ($Config{useshrplib} eq 'true') {
        my $libperl = '$(PERL_INC)' .'/'. "$Config{libperl}";
        if( $] >= 5.006002 ) {
            $libperl =~ s/a$/dll.a/;
        }
        $self->{PERL_ARCHIVE} = $libperl;
    } else {
        $self->{PERL_ARCHIVE} = 
          '$(PERL_INC)' .'/'. ("$Config{libperl}" or "libperl.a");
    }

$self->{PERL_ARCHIVE_AFTER} ||= '';
    $self->{EXPORT_LIST}  ||= '';
}

=item maybe_command

If our path begins with F</cygdrive/> then we use C<ExtUtils::MM_Win32>
to determine if it may be a command.  Otherwise we use the tests
from C<ExtUtils::MM_Unix>.

=cut

sub maybe_command {
    my ($self, $file) = @_;

if ($file =~ m{^/cygdrive/}i) {
        return ExtUtils::MM_Win32->maybe_command($file);
    }

return $self->SUPER::maybe_command($file);
}

=item dynamic_lib

Use the default to produce the *.dll's.
But for new archdir dll's use the same rebase address if the old exists.

=cut

sub dynamic_lib {
    my($self, %attribs) = @_;
    my $s = ExtUtils::MM_Unix::dynamic_lib($self, %attribs);
    my $ori = "$self->{INSTALLARCHLIB}/auto/$self->{FULLEXT}/$self->{BASEEXT}.$self->{DLEXT}";
    if (-e $ori) {
        my $imagebase = `/bin/objdump -p $ori | /bin/grep ImageBase | /bin/cut -c12-`;
        chomp $imagebase;
        if ($imagebase gt "40000000") {
            my $LDDLFLAGS = $self->{LDDLFLAGS};
            $LDDLFLAGS =~ s/-Wl,--enable-auto-image-base/-Wl,--image-base=0x$imagebase/;
            $s =~ s/ \$$LDDLFLAGS$ / $LDDLFLAGS /m;
        }
    }
    $s;
}

=item all_target

Build man pages, too

=cut

sub all_target {
    ExtUtils::MM_Unix::all_target(shift);
}

=back

=cut

${this.title}

Code Editor : MM_Cygwin.pm